Shader "StudioMaron/PsylliumAudience"
{
    Properties
    {
		[Header(_____________________________________________________________________________________________)]
		[Header(Rendering)]
		[Space(10)]
		[KeywordEnum(Off, Front, Back)] _Cull("    Cull Mode", Int) = 2
		[Header(_____________________________________________________________________________________________)]
		[Header(Base)]
		[Space(10)]
		_Color("    Color", Color) = (1,1,1,1)
		_MainTex("    Main Texture", 2D) = "white"{}
		_Cutoff ("    Alpha Cutoff", Range(0, 1)) = 0.5
		[Header(Emission)]
		[Space(10)]
		[HDR]_EmissionColor("    Emission Color", Color) = (0,0,0,1)
		_EmissionMask("    Emission Mask", 2D) = "white"{}
		_EmissionIntensity ("    Emission Intensity", Float) = 1
		[Header(_____________________________________________________________________________________________)]
		[Header(Jump)]
		[Space(10)]
		[KeywordEnum(Auto, Manual)] _JumpMode("    Jump Mode" , Float) = 0
		_JumpHeight ("    Jump Height", Range(0, 1)) = 0.1
		_JumpInterval ("    Auto: Interval", Float) = 0.6
		_JumpIntervalOffset ("    Auto: Interval Offset", Range(0, 1)) = 0.0
		_JumpControl ("    Manual: Control", Range(0, 1)) = 0.0
    }
    SubShader
    {
        Tags { "RenderType"="Opaque" }
        LOD 100

        Pass
        {
			Cull[_Cull]

            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            // make fog work
            #pragma multi_compile_fog

            #include "UnityCG.cginc"

            #define PI 3.141592658979

            struct appdata
            {
                float4 vertex : POSITION;
                float2 uv : TEXCOORD0;
            };

            struct v2f
            {
                float2 uv : TEXCOORD0;
                UNITY_FOG_COORDS(1)
                float4 vertex : SV_POSITION;
            };

            sampler2D _MainTex;
            float4 _MainTex_ST;
            float4 _Color;
            float _Cutoff;

            sampler2D _EmissionMask;
            float4 _EmissionColor;
            float _EmissionIntensity;

            float _JumpMode;
            float _JumpHeight;
            float _JumpInterval;
            float _JumpIntervalOffset;
            float _JumpControl;

            v2f vert (appdata v)
            {
                v2f o;
                float4 worldPos = mul(unity_ObjectToWorld, v.vertex); // ローカル空間 → ワールド空間

                ////////////////////////////////////////////////////////
                // Jump
                ////////////////////////////////////////////////////////
                float jumpHeight = _JumpHeight;
                float jumpInterval = _JumpIntervalOffset + PI * _Time.y / _JumpInterval;
                float jumpControl =_JumpControl;
                switch(_JumpMode)
                {
                    case 0: // Auto
                        worldPos.y += jumpHeight * abs(sin(jumpInterval));
                        break;

                    case 1: // Manual
                        worldPos.y += jumpHeight * jumpControl;
                        break;

                }
                
                float4 viewPos  = mul(UNITY_MATRIX_V, worldPos); // ワールド空間 → ビュー空間
                float4 clipPos  = mul(UNITY_MATRIX_P, viewPos); // ビュー空間 → クリップ空間
                o.vertex = clipPos;
                o.uv = TRANSFORM_TEX(v.uv, _MainTex);
                UNITY_TRANSFER_FOG(o,o.vertex);
                return o;
            }

            float4 frag (v2f i) : SV_Target
            {
                // sample the texture
                float4 col = tex2D(_MainTex, i.uv);
                clip(col.a - _Cutoff);
                col *= _Color;

                float4 emission = tex2D(_EmissionMask, i.uv) * _EmissionColor * _EmissionIntensity;
				col = lerp(col, emission, saturate(_EmissionIntensity));

                // apply fog
                UNITY_APPLY_FOG(i.fogCoord, col);
                return col;
            }
            ENDCG
        }
    }
}